import "pkg:/source/api/ApiClient.bs"
import "pkg:/source/utils/nodeHelpers.bs"
import "pkg:/source/utils/streamSelection.bs"
' All of the Quick Play logic seperated by media type
namespace quickplay
' Takes an array of items and adds to global queue.
' Also shuffles the playlist if asked
sub pushToQueue(queueArray as object, shufflePlay = false as boolean)
if isValidAndNotEmpty(queueArray)
for each item in queueArray
m.global.queueManager.callFunc("push", nodeHelpers.createQueueItem(item))
end for
' shuffle the playlist if asked
if shufflePlay and m.global.queueManager.callFunc("getCount") > 1
m.global.queueManager.callFunc("toggleShuffle")
end if
end if
end sub
' A single video file.
sub video(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) or itemNode.id = "" then return
' Create a queue-specific item to avoid modifying the UI node
' This prevents the quickPlayNode field observer from firing twice
queueItem = nodeHelpers.createQueueItem(itemNode)
if not isValid(queueItem) then return
' Get user session for audio selection
localUser = m.global.user
' audioStreams is pre-filtered to audio-only by the transformer.
' findBestAudioStreamIndex filters by Type="audio" internally, so passing
' pre-filtered audio streams works correctly.
audioStreamIndex = 0
if isValidAndNotEmpty(itemNode.audioStreams)
playDefault = resolvePlayDefaultAudioTrack(localUser.settings, localUser.config)
audioStreamIndex = findBestAudioStreamIndex(itemNode.audioStreams, playDefault, localUser.config.audioLanguagePreference)
end if
' Resume position from typed field; startingPoint is computed here, not stored on node
playbackPosition = itemNode.playbackPositionTicks
queueItem.selectedAudioStreamIndex = audioStreamIndex
queueItem.startingPoint = playbackPosition
m.global.queueManager.callFunc("push", queueItem)
end sub
' A single audio file.
sub audio(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' Create a queue-specific item to avoid modifying the UI node
queueItem = nodeHelpers.createQueueItem(itemNode)
if not isValid(queueItem) then return
m.global.queueManager.callFunc("push", queueItem)
end sub
' A single music video file.
sub musicVideo(itemNode as object)
if not isValid(itemNode) or not isValidAndNotEmpty(itemNode.id) then return
' Create a queue-specific item to avoid modifying the UI node
queueItem = nodeHelpers.createQueueItem(itemNode)
if not isValid(queueItem) then return
m.global.queueManager.callFunc("push", queueItem)
end sub
' A single photo.
sub photo(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
photoPlayer = CreateObject("roSgNode", "PhotoDetails")
photoPlayer.itemsNode = itemNode
photoPlayer.itemIndex = 0
m.global.sceneManager.callfunc("pushScene", photoPlayer)
end sub
' A photo album.
sub photoAlbum(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' grab all photos inside photo album
photoAlbumData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"includeItemTypes": "Photo",
"sortBy": "Random",
"Recursive": true
})
print "photoAlbumData=", photoAlbumData
if isValid(photoAlbumData) and isValidAndNotEmpty(photoAlbumData.items)
photoPlayer = CreateObject("roSgNode", "PhotoDetails")
photoPlayer.isSlideshow = true
photoPlayer.isRandom = false
photoPlayer.itemsArray = photoAlbumData.items
photoPlayer.itemIndex = 0
m.global.sceneManager.callfunc("pushScene", photoPlayer)
else
stopLoadingSpinner()
end if
end sub
' A music album.
' Play the entire album starting with track 1.
sub album(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' grab list of songs in the album
albumSongs = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"imageTypeLimit": 1,
"sortBy": "SortName",
"limit": 500,
"enableUserData": false,
"EnableTotalRecordCount": false
})
if isValid(albumSongs) and isValidAndNotEmpty(albumSongs.items)
quickplay.pushToQueue(albumSongs.items)
else
stopLoadingSpinner()
end if
end sub
' A music artist.
' Shuffle play all songs by artist.
sub artist(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' get all songs by artist
artistSongs = GetApi().GetItemsByQuery({
"artistIds": itemNode.id,
"includeItemTypes": "Audio",
"sortBy": "Album",
"limit": 500,
"imageTypeLimit": 1,
"Recursive": true,
"enableUserData": false,
"EnableTotalRecordCount": false
})
print "artistSongs=", artistSongs
if isValid(artistSongs) and isValidAndNotEmpty(artistSongs.items)
quickplay.pushToQueue(artistSongs.items, true)
else
stopLoadingSpinner()
end if
end sub
' A boxset.
' Play all items inside.
sub boxset(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
data = GetApi().GetByQuery({
"userid": m.global.user.id,
"parentid": itemNode.id,
"limit": 500,
"EnableTotalRecordCount": false
})
if isValid(data) and isValidAndNotEmpty(data.Items)
quickplay.pushToQueue(data.items)
else
stopLoadingSpinner()
end if
end sub
' A TV Show Series.
' Prefer an in-progress (resumable) episode — consistent with the Continue Watching row.
' Falls back to the next unstarted/unwatched episode (ep 1 for a fresh series).
' If all episodes are fully watched and rewatching is disabled, shuffle the whole series.
sub series(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' ONE rendezvous to get user
localUser = m.global.user
' Check for a resumable (in-progress) episode first
resumeData = GetApi().GetResumeItems({
"parentId": itemNode.id,
"userid": localUser.id,
"Filters": "IsResumable",
"SortBy": "DatePlayed",
"SortOrder": "Descending",
"Limit": 1,
"recursive": true,
"ImageTypeLimit": 1,
"EnableTotalRecordCount": false
})
if isValid(resumeData) and isValidAndNotEmpty(resumeData.Items)
' play the resumable episode
queueItem = nodeHelpers.createQueueItem(resumeData.Items[0])
if isValid(resumeData.Items[0].UserData) and isValid(resumeData.Items[0].UserData.PlaybackPositionTicks)
queueItem.startingPoint = resumeData.Items[0].UserData.PlaybackPositionTicks
end if
m.global.queueManager.callFunc("push", queueItem)
else
' Fall back to next unstarted episode.
' DisableFirstEpisode: false so a completely unwatched series starts at episode 1.
data = GetApi().GetNextUp({
"seriesId": itemNode.id,
"UserId": localUser.id,
"Limit": 1,
"DisableFirstEpisode": false,
"ImageTypeLimit": 1,
"EnableRewatching": localUser.settings.uiDetailsEnableRewatchingNextUp,
"EnableTotalRecordCount": false
})
if isValid(data) and isValidAndNotEmpty(data.Items)
m.global.queueManager.callFunc("push", nodeHelpers.createQueueItem(data.Items[0]))
else
' All episodes fully watched and rewatching disabled — shuffle the whole series
data = GetApi().GetEpisodes(itemNode.id, {
"userid": localUser.id,
"SortBy": "Random",
"limit": 500,
"EnableTotalRecordCount": false
})
if isValid(data) and isValidAndNotEmpty(data.Items)
quickplay.pushToQueue(data.Items)
else
stopLoadingSpinner()
end if
end if
end if
end sub
' More than one TV Show Series.
' Shuffle play all watched episodes
sub multipleSeries(itemNodes as object)
if isValidAndNotEmpty(itemNodes)
' ONE rendezvous to get user ID
userId = m.global.user.id
numTotal = 0
numLimit = 500
for each tvshow in itemNodes
' grab all watched episodes for each series
showData = GetApi().GetEpisodes(tvshow.id, {
"userId": userId,
"SortBy": "Random",
"imageTypeLimit": 0,
"EnableTotalRecordCount": false,
"enableImages": false
})
if isValid(showData) and isValidAndNotEmpty(showData.items)
playedEpisodes = []
' add all played episodes to queue
for each episode in showData.items
if isValid(episode.userdata) and isValid(episode.userdata.Played)
if episode.userdata.Played
playedEpisodes.push(episode)
end if
end if
end for
quickplay.pushToQueue(playedEpisodes)
' keep track of how many items we've seen
numTotal = numTotal + showData.items.count()
if numTotal >= numLimit
' stop grabbing more items if we hit our limit
exit for
end if
end if
end for
if m.global.queueManager.callFunc("getCount") > 1
m.global.queueManager.callFunc("toggleShuffle")
else
stopLoadingSpinner()
end if
end if
end sub
' A container with some kind of videos inside of it
sub videoContainer(itemNode as object)
print "itemNode=", itemNode
collectionType = Lcase(itemNode.collectionType)
if collectionType = "movies"
' get randomized list of videos inside
data = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"sortBy": "Random",
"recursive": true,
"includeItemTypes": "Movie,Video",
"limit": 500
})
print "data=", data
if isValid(data) and isValidAndNotEmpty(data.items)
videoList = []
' add each item to the queue
for each item in data.Items
print "data.Item=", item
' only add videos we're not currently watching
if isValid(item.userdata) and isValid(item.userdata.PlaybackPositionTicks)
if item.userdata.PlaybackPositionTicks = 0
videoList.push(item)
end if
end if
end for
quickplay.pushToQueue(videoList)
else
stopLoadingSpinner()
end if
return
else if collectionType = "tvshows" or collectionType = "collectionfolder"
' get list of tv shows inside
tvshowsData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"sortBy": "Random",
"recursive": true,
"excludeItemTypes": "Season",
"imageTypeLimit": 0,
"enableUserData": false,
"EnableTotalRecordCount": false,
"enableImages": false
})
print "tvshowsData=", tvshowsData
if isValid(tvshowsData) and isValidAndNotEmpty(tvshowsData.items)
' the type of media returned from api may change.
if tvshowsData.items[0].Type = "Series"
quickplay.multipleSeries(tvshowsData.items)
else
' if first item is not a series, then assume they are all videos and/or episodes
quickplay.pushToQueue(tvshowsData.items)
end if
else
stopLoadingSpinner()
end if
else
stopLoadingSpinner()
print "Quick Play videoContainer WARNING: Unknown collection type"
end if
end sub
' A TV Show Season.
' Play the first unwatched episode.
' If none, play the whole season starting with episode 1.
sub season(itemNode as object)
globalUser = m.global.user
if not isValid(itemNode) or not isValid(itemNode.id) then return
seriesId = itemNode.seriesId
unwatchedData = GetApi().GetEpisodes(seriesId, {
"seasonId": itemNode.id,
"userid": globalUser.id,
"limit": 500,
"EnableTotalRecordCount": false
})
if isValid(unwatchedData) and isValidAndNotEmpty(unwatchedData.Items)
' find the first unwatched episode
firstUnwatchedEpisodeIndex = invalid
resumePosition = 0
for each item in unwatchedData.Items
if isValid(item.UserData)
if isValid(item.UserData.Played) and item.UserData.Played = false
firstUnwatchedEpisodeIndex = isValid(item.IndexNumber) ? item.IndexNumber - 1 : 0
if isValid(item.UserData.PlaybackPositionTicks)
resumePosition = item.UserData.PlaybackPositionTicks
end if
exit for
end if
end if
end for
if isValid(firstUnwatchedEpisodeIndex)
' add the first unwatched episode and the rest of the season to a playlist
for i = firstUnwatchedEpisodeIndex to unwatchedData.Items.count() - 1
queueItem = nodeHelpers.createQueueItem(unwatchedData.Items[i])
if i = firstUnwatchedEpisodeIndex then queueItem.startingPoint = resumePosition
m.global.queueManager.callFunc("push", queueItem)
end for
else
' try to find a "continue watching" episode
continueData = GetApi().GetResumeItems({
"parentId": itemNode.id,
"userid": globalUser.id,
"SortBy": "DatePlayed",
"recursive": true,
"SortOrder": "Descending",
"Filters": "IsResumable",
"EnableTotalRecordCount": false
})
if isValid(continueData) and isValidAndNotEmpty(continueData.Items)
' play the resumable episode
for each item in continueData.Items
queueItem = nodeHelpers.createQueueItem(item)
if isValid(item.UserData) and isValid(item.UserData.PlaybackPositionTicks)
queueItem.startingPoint = item.UserData.PlaybackPositionTicks
end if
m.global.queueManager.callFunc("push", queueItem)
end for
else
' play the whole season in order
if isValid(unwatchedData) and isValidAndNotEmpty(unwatchedData.Items)
' add all episodes found to a playlist
pushToQueue(unwatchedData.Items)
end if
end if
end if
else
stopLoadingSpinner()
end if
end sub
' Quick Play A Person.
' Shuffle play all movies and episodes found for this person
sub person(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' get movies by the person
personMovies = GetApi().GetItemsByQuery({
"personIds": itemNode.id,
"includeItemTypes": "Movie",
"excludeItemTypes": "Season,Series",
"recursive": true,
"limit": 500
})
print "personMovies=", personMovies
if isValid(personMovies) and isValidAndNotEmpty(personMovies.Items)
' add each item to the queue
quickplay.pushToQueue(personMovies.Items)
end if
' get watched episodes by the person
personEpisodes = GetApi().GetItemsByQuery({
"personIds": itemNode.id,
"includeItemTypes": "Episode,Recording",
"isPlayed": true,
"excludeItemTypes": "Season,Series",
"recursive": true,
"limit": 500
})
print "personEpisodes=", personEpisodes
if isValid(personEpisodes) and isValidAndNotEmpty(personEpisodes.Items)
' add each item to the queue
quickplay.pushToQueue(personEpisodes.Items)
end if
if m.global.queueManager.callFunc("getCount") > 1
m.global.queueManager.callFunc("toggleShuffle")
else
stopLoadingSpinner()
end if
end sub
' Quick Play A TVChannel
sub tvChannel(itemNode as object)
if not isValid(itemNode) or not isValidAndNotEmpty(itemNode.id)
print "ERROR: quickplay.tvChannel() - missing itemNode or id"
stopLoadingSpinner()
return
end if
' Push TV channel queue item — keep spinner active until video content loads
m.global.queueManager.callFunc("push", nodeHelpers.createQueueItem(itemNode))
end sub
' Quick Play A Live Program
sub program(itemNode as object)
if not isValid(itemNode) or not isValidAndNotEmpty(itemNode.channelId)
print "ERROR: quickplay.program() - missing ChannelId"
stopLoadingSpinner()
return
end if
' Play the channel this program is on, not the program itself.
' Override id and type on the queue item so the playback pipeline targets the channel.
' Keep spinner active until video content loads.
queueItem = nodeHelpers.createQueueItem(itemNode)
queueItem.id = itemNode.channelId
queueItem.type = "TvChannel"
m.global.queueManager.callFunc("push", queueItem)
end sub
' Quick Play A Playlist.
' Play the first unwatched episode.
' If none, play the whole season starting with episode 1.
sub playlist(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' get playlist items
myPlaylist = GetApi().GetPlaylistItems(itemNode.id, {
"userId": m.global.user.id,
"limit": 500
})
if isValid(myPlaylist) and isValidAndNotEmpty(myPlaylist.Items)
' add each item to the queue
quickplay.pushToQueue(myPlaylist.Items)
if m.global.queueManager.callFunc("getCount") > 1
m.global.queueManager.callFunc("toggleShuffle")
end if
else
stopLoadingSpinner()
end if
end sub
' Quick Play A folder.
' Shuffle play all items found
sub folder(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
paramArray = {
"includeItemTypes": ["Episode", "Recording", "Movie", "Video"],
"videoTypes": "VideoFile",
"sortBy": "Random",
"limit": 500,
"imageTypeLimit": 1,
"Recursive": true,
"enableUserData": false,
"EnableTotalRecordCount": false
}
' modify api query based on folder type
' After transformer fix: Genre/MusicGenre/Studio items have type="Folder" and
' folderType="Genre"/"MusicGenre"/"Studio". Plain folders have folderType="".
folderType = Lcase(itemNode.folderType)
print "folderType=", folderType
if folderType = "studio"
paramArray["studioIds"] = itemNode.id
else if folderType = "genre"
paramArray["genreIds"] = itemNode.id
if itemNode.movieCount > 0
paramArray["includeItemTypes"] = "Movie"
end if
else if folderType = "musicgenre"
paramArray["genreIds"] = itemNode.id
paramArray.delete("videoTypes")
paramArray["includeItemTypes"] = "Audio"
else if folderType = "photoalbum"
paramArray["parentId"] = itemNode.id
paramArray["includeItemTypes"] = "Photo"
paramArray.delete("videoTypes")
paramArray.delete("Recursive")
else
paramArray["parentId"] = itemNode.id
end if
' look for tv series instead of video files
if itemNode.seriesCount > 0
paramArray["includeItemTypes"] = "Series"
paramArray.Delete("videoTypes")
end if
' get folder items
folderData = GetApi().GetItemsByQuery(paramArray)
print "folderData=", folderData
if isValid(folderData) and isValidAndNotEmpty(folderData.items)
if itemNode.seriesCount > 0
if itemNode.seriesCount = 1
quickplay.series(folderData.items[0])
else
quickplay.multipleSeries(folderData.items)
end if
else
if folderType = "photoalbum"
photoPlayer = CreateObject("roSgNode", "PhotoDetails")
photoPlayer.isSlideshow = true
photoPlayer.isRandom = false
photoPlayer.itemsArray = folderData.items
photoPlayer.itemIndex = 0
m.global.sceneManager.callfunc("pushScene", photoPlayer)
else
quickplay.pushToQueue(folderData.items, true)
end if
end if
else
stopLoadingSpinner()
end if
end sub
' Quick Play A CollectionFolder.
' Shuffle play the items inside
' with some differences based on collectionType.
sub collectionFolder(itemNode as object)
if not isValid(itemNode) or not isValid(itemNode.id) then return
' play depends on the kind of files inside the collectionfolder
print "attempting to quickplay a collection folder"
collectionType = LCase(itemNode.collectionType)
print "collectionType=", collectionType
if collectionType = "movies"
quickplay.videoContainer(itemNode)
else if collectionType = "music"
' get audio files from under this collection
' sort songs by album then artist
songsData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"includeItemTypes": "Audio",
"sortBy": "Album",
"Recursive": true,
"limit": 500,
"imageTypeLimit": 1,
"enableUserData": false,
"EnableTotalRecordCount": false
})
print "songsData=", songsData
if isValid(songsData) and isValidAndNotEmpty(songsData.items)
quickplay.pushToQueue(songsData.Items, true)
else
stopLoadingSpinner()
end if
else if collectionType = "boxsets"
' get list of all boxsets inside
boxsetData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"limit": 500,
"imageTypeLimit": 0,
"enableUserData": false,
"EnableTotalRecordCount": false,
"enableImages": false
})
print "boxsetData=", boxsetData
if isValid(boxsetData) and isValidAndNotEmpty(boxsetData.items)
' pick a random boxset
arrayIndex = Rnd(boxsetData.items.count()) - 1
myBoxset = boxsetData.items[arrayIndex]
' grab list of items from boxset
print "myBoxset=", myBoxset
boxsetData = GetApi().GetItemsByQuery({
"parentId": myBoxset.id,
"EnableTotalRecordCount": false
})
if isValid(boxsetData) and isValidAndNotEmpty(boxsetData.items)
' add all boxset items to queue
quickplay.pushToQueue(boxsetData.Items)
else
stopLoadingSpinner()
end if
end if
else if collectionType = "tvshows" or collectionType = "collectionfolder"
quickplay.videoContainer(itemNode)
else if collectionType = "musicvideos"
' get randomized list of videos inside
data = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"includeItemTypes": "MusicVideo",
"sortBy": "Random",
"Recursive": true,
"limit": 500,
"imageTypeLimit": 1,
"enableUserData": false,
"EnableTotalRecordCount": false
})
print "data=", data
if isValid(data) and isValidAndNotEmpty(data.items)
quickplay.pushToQueue(data.Items)
else
stopLoadingSpinner()
end if
else if collectionType = "homevideos"
' Photo library - items can be type video, photo, or photoAlbum
' grab all photos inside library
folderData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"includeItemTypes": "Photo",
"sortBy": "Random",
"Recursive": true
})
print "folderData=", folderData
if isValid(folderData) and isValidAndNotEmpty(folderData.items)
photoPlayer = CreateObject("roSgNode", "PhotoDetails")
photoPlayer.isSlideshow = true
photoPlayer.isRandom = false
photoPlayer.itemsArray = folderData.items
photoPlayer.itemIndex = 0
m.global.sceneManager.callfunc("pushScene", photoPlayer)
else
stopLoadingSpinner()
end if
else
stopLoadingSpinner()
print "Quick Play WARNING: Unknown collection type"
end if
end sub
' Quick Play A UserView.
' Play logic depends on "collectionType".
sub userView(itemNode as object)
globalUser = m.global.user
' play depends on the kind of files inside the collectionfolder
collectionType = LCase(itemNode.collectionType)
print "collectionType=", collectionType
if collectionType = "playlists"
' get list of all playlists inside
playlistData = GetApi().GetItemsByQuery({
"parentId": itemNode.id,
"imageTypeLimit": 0,
"enableUserData": false,
"EnableTotalRecordCount": false,
"enableImages": false
})
print "playlistData=", playlistData
if isValid(playlistData) and isValidAndNotEmpty(playlistData.items)
' pick a random playlist
arrayIndex = Rnd(playlistData.items.count()) - 1
myPlaylist = playlistData.items[arrayIndex]
' grab list of items from playlist
print "myPlaylist=", myPlaylist
playlistItems = GetApi().GetPlaylistItems(myPlaylist.id, {
"userId": globalUser.id,
"EnableTotalRecordCount": false,
"limit": 500
})
' validate api results
if isValid(playlistItems) and isValidAndNotEmpty(playlistItems.items)
quickplay.pushToQueue(playlistItems.items, true)
else
stopLoadingSpinner()
end if
end if
else if collectionType = "livetv"
' get list of all tv channels
channelData = GetApi().GetItemsByQuery({
"includeItemTypes": "TVChannel",
"sortBy": "Random",
"Recursive": true,
"imageTypeLimit": 0,
"enableUserData": false,
"EnableTotalRecordCount": false,
"enableImages": false
})
print "channelData=", channelData
if isValid(channelData) and isValidAndNotEmpty(channelData.items)
' pick a random channel
arrayIndex = Rnd(channelData.items.count()) - 1
myChannel = channelData.items[arrayIndex]
print "myChannel=", myChannel
' play channel
quickplay.tvChannel(myChannel)
else
stopLoadingSpinner()
end if
else if collectionType = "movies"
quickplay.videoContainer(itemNode)
else if collectionType = "tvshows"
quickplay.videoContainer(itemNode)
else
stopLoadingSpinner()
print "Quick Play CollectionFolder WARNING: Unknown collection type"
end if
end sub
end namespace